不太清楚你的具体情况
写代码是根据不同情况来写的

where inlist(ALLTRIM(信息名称),jj1,jj2,jj3,jj4,jj5,jj6)

   选择相应的复选框，来筛选数据

where inlist(ALLTRIM(信息名称),jj1,jj2,jj3,jj4,jj5,jj6)


这样显示的是所有数据

给你一个例子参考，是不是这样的

[此贴子已经被作者于2018-10-14 17:03编辑过]

local jj,jj1,jj2,jj3,jj4,jj5,jj6
jj1=thisform.check1.value
jj2=thisform.check2.value
jj3=thisform.check3.value
jj4=thisform.check4.value
jj5=thisform.check5.value
jj6=thisform.check6.value
jj = ""
jj = IIF(jj1=0,jj,IIF(EMPTY(jj),[allt(信息名称),"春"],jj + [,"春"]))
jj = IIF(jj2=0,jj,IIF(EMPTY(jj),[allt(信息名称),"夏"],jj + [,"夏"]))
jj = IIF(jj3=0,jj,IIF(EMPTY(jj),[allt(信息名称),"秋"],jj + [,"秋"]))
jj = IIF(jj4=0,jj,IIF(EMPTY(jj),[allt(信息名称),"冬"],jj + [,"冬"]))
jj = IIF(jj5=0,jj,IIF(EMPTY(jj),[allt(信息名称),"春夏"],jj + [,"春夏"]))
jj = IIF(jj6=0,jj,IIF(EMPTY(jj),[allt(信息名称),"秋冬"],jj + [,"秋冬"]))
if empty(jj)
   select * FROM 基础信息 INTO CURSOR ls
else
   select * FROM 基础信息 where INLIST(&jj) INTO CURSOR ls
endif

查询按钮下代码
Local jj[6]
lcTj = ""
For i = 1 To 6
    lcCheck = "Check"+Str(i, 1)
    If ThisForm.&lcCheck..Value = 1
        jj[i] = ThisForm.&lcCheck..Caption
    Else
        jj[i] = ""
    EndIf
    lcTj = lcTj + Iif(Empty(jj[i]), "", ' OR Alltrim(信息名称)==' + "'"+jj[i] + "'")
EndFor
lcTj = Substr(lcTj, 5)
If Empty(lcTj)
    MessageBox("请选择查询内容")
    Return
EndIf
MessageBox(lcTj, 0, "查询条件")
Select * From ss Where &lcTj

结果

[此贴子已经被作者于2018-10-14 22:56编辑过]

只要保证字符串中的每个项目都加上字符串定界符即可。
示例1：
cjj =  "[秋],[冬]"
sele * from 其他信息 where all(信息名称) in (&cjj)
示例2：
c1 = thisform.check1.caption
c2 = thisform.check2.caption
cjj = ""
if !empty(thisform.check1.value)
    cjj = cjj + ",[" + thisform.check1.caption + "]"
endif
if !empty(thisform.check2.value)
    cjj = cjj + ",[" + thisform.check2.caption + "]"
endif
cjj = subs(cjj,2)
sele * from 其他信息 where all(信息名称) in (&cjj)

特别提示：使用 select 语句的 in 子名时，要注意 set ansi on/off的设置，精确比较时，应采用 set ansi on，相当于 set exact on；不精确比较时，应采用 set ansi off（默认），相当于 set exact off

[此贴子已经被作者于2018-10-15 08:57编辑过]

谢谢各位老大

向各位大佬学习，谢谢！