程序代码：

CREATE CURSOR ys1 (lxfs C(10))
INSERT INTO ys1 VALUES ("1001")
INSERT INTO ys1 VALUES ("1002")
INSERT INTO ys1 VALUES ("1003")
INSERT INTO ys1 VALUES ("1004")
CREATE CURSOR fs1 (lxfs C(10))
INSERT INTO fs1 VALUES ("1001")
INSERT INTO fs1 VALUES ("1003")
INSERT INTO fs1 VALUES ("1005")
INSERT INTO fs1 VALUES ("1006")

SELECT ys1
INDEX on lxfs TAG tag_ys1
SELECT fs1
INDEX on lxfs TAG tag_fs1

? "ys1 NOT IN fs1"
SELECT ys1
SET RELATION TO lxfs INTO "fs1"
LIST FOR !FOUND("fs1")
SET RELATION TO

? "fs1 NOT IN ys1"
SELECT fs1
SET RELATION TO lxfs INTO "ys1"
LIST FOR !FOUND("ys1")
SET RELATION TO

[此贴子已经被作者于2021-8-20 17:04编辑过]

[此贴子已经被作者于2021-8-20 19:08编辑过]

程序代码：

** 测试数据
CREATE CURSOR ys1 (lxfs C(10))
FOR i=1 TO 300000
    INSERT INTO ys1 VALUES (PADL(i,7,"0"))
ENDFOR
CREATE CURSOR fs1 (lxfs C(10))
APPEND FROM DBF("ys1")
SELECT ys1
GO TOP 
REPLACE lxfs WITH "ys1_000001"
GO BOTTOM 
REPLACE lxfs WITH "ys1_100000"

t = SECONDS()
SELECT ALLTRIM(lxfs) AS MY_KEY from fs1 DIST NOCO INTO TABLE TEMP_KEY
SELECT * FROM ys1 where ALLTRIM(lxfs) NOT in(SELECT MY_KEY FROM TEMP_KEY) NOWAIT   
?SECONDS()-t && 5.5s

** 去掉ALLTRIM
t = SECONDS()
SELECT lxfs AS MY_KEY from fs1 DIST NOCO INTO TABLE TEMP_KEY
SELECT * FROM ys1 where lxfs NOT in(SELECT MY_KEY FROM TEMP_KEY) NOWAIT   
?SECONDS()-t && 5.0s

t = SECONDS()
SELECT fs1
INDEX on lxfs TAG tag_fs1
SELECT ys1
SET RELATION TO lxfs INTO "fs1"
COPY TO tmp FOR !FOUND("fs1")
SET RELATION TO
?SECONDS()-t && 3.5s
SELECT * FROM tmp NOWAIT 

对比数据.rar (2.08 MB)

[此贴子已经被作者于2021-8-20 21:21编辑过]