还可以这样的。
你的是遇到取的最后1位是双字节的第1位时，舍去。
4楼是遇到取的最后1位是双字节的第1位时，取多1位。

把你的和4楼的整合起来，就可以选择最后1为是舍去还是保留了。或者用7楼
整合后如下：
CLEAR


Str1 = "123456人发可个方和方经品他三方登山泛水多福多寿辅导费对方012345678901nLen1-1456789"
nLen1=31

? CutStr(str1,nLen1,0)
? CutStr(str1,nLen1,1)
? _CutStr(str1,nLen1,0)
? _CutStr(str1,nLen1,1)

*!* ======================================
*!* 先计算最后1位是双字节的第1位还是第2位
*!* 根据选择是舍弃还是保留最后1位的双字节
*!* ======================================
FUNCTION CutStr(cStr1,nLen1,nAdd)
LOCAL N1,cStr2

*!* 强行将参数值转换为字符串，并去掉字符串右边的空格
cStr1 = RTRIM(TRANSFORM(cStr1))

*!* 长度参数错误或者大于字符串长度，取字符串最大长度
N1 = LEN(cStr1)
nLen1 = IIF(TYPE("nLen1") # "N",N1,IIF(nLen1>N1,N1,nLen1))

*!* 截取的最后一个字符是半个双字节时，是舍去还是保留
nAdd = IIF(TYPE("nAdd") # "N",0,IIF(nAdd = 1,1,0))

if N1 > nLen1
   LOCAL i,nCount
   nCount = 0
   *!* 计算字符是双字节还是单字节，是第1位还是第2位
   FOR i=1 TO nLen1
       IF ISLEADBYTE(SUBSTR(cStr1,i,1)) = .T. &&判断双字节时计数 +1
          nCount = nCount + 1
       ENDIF
   ENDFOR

   IF ISLEADBYTE(SUBSTR(cStr1,i,1)) = .T. &&判断是不是双字节
      IF MOD(nCount,2)=0 &&判断是否双字节的第2位
         cStr2=SUBSTR(cStr1,1,nLen1)
      ELSE
         cStr2=IIF(nAdd = 0,SUBSTR(cStr1,1,nLen1-1),SUBSTR(cStr1,1,nLen1+1))
      ENDIF
   ELSE  
      cStr2=SUBSTR(cStr1,1,nLen1)
   ENDIF
ELSE
   cStr2 = cStr1   
ENDIF

RETURN cStr2
ENDFUNC

*!  ========================================================
*!* 利用4楼和10方法整合后，可以选择舍去还是保留最后1位双字节
*!  ========================================================
FUNCTION _CutStr(cStr1,nLen1,nAdd)
  LOCAL nCount,N1

  *!* 强行将参数值转换为字符串，并去掉字符串右边的空格
  cStr1 = RTRIM(TRANSFORM(cStr1))

  *!* 长度参数错误或者大于字符串长度，取字符串最大长度
  N1 = LEN(cStr1)
  nLen1 = IIF(TYPE("nLen1") # "N",N1,IIF(nLen1>N1,N1,nLen1))

  *!* 截取的最后一个字符是半个双字节时，是舍去还是保留
  nAdd = IIF(TYPE("nAdd") # "N",0,IIF(nAdd = 1,1,0))

  IF nAdd = 0
     RETURN SUBSTRC(LEFT(cStr1,nLen1),1)
  ELSE
     nCount = 0
     DO WHILE nCount < nLen1
        nCount = nCount + IIF(ISLEADBYTE(SUBSTR(cStr1,nCount+1,1)), 2, 1)
     ENDDO
     RETURN LEFT(cStr1,nCount)
  ENDIF
  
ENDFUNC

[此贴子已经被作者于2017-2-25 12:16编辑过]

活用就可以了
Str1 = "12345人发可个方和方经品他三方登山泛水多福多寿辅导费对方012345678901nLen1-1456789"
nLen1=32
?SUBSTRC(LEFT(str1,nLen1),1)  &遇到取的最后1位是双字节的第1位时，舍去.
?LEFT(str1,2*nLen1-LEN(SUBSTRC(LEFT(str1,nLen1),1)))  &&遇到取的最后1位是双字节的第1位时，取多1位.

[此贴子已经被作者于2017-2-25 12:39编辑过]

看高手论道真是一种享受。谢谢！

这个问题当年曾困扰我很久，如何避免取出的是乱码？真的伤脑筋。尤其中英文混的字符串，幸好有你们。

对于纯文本数据，就是由键盘正常编辑输入的字符（特殊输入的不算，如Ctrl+XXX或Alt+XXX等），这类纯文本数据还有规律可寻，比较好处理。对于一些字节流的数据（如二进制文件数据或网络数据），要在其中取出一段内容的文字显示而不出现“乱码”，除了逐字节分析，还有没有更简的方法？

吹版，Kiff 提到的，先用 substr()或者left()取，然后再用 substrc()取，他会把第1次取的，如果最后1位是乱码的去掉的。
不知道，你说的“对于一些字节流的数据（如二进制文件数据或网络数据）”能否适应这种方法，他不用循环，速度比“逐字节分析”快很多。

如果一个文本字节数达到MB级，SUBSTR()速度还是很慢的，最快的方法是fopen(),fread(),fseek()配合使用速度最快

好象这类文件数据，每行显示16个字节，左边用内码显示，右边用文本显示，非打印字符是用“.”表示，但那个“?”好象有点“乱码”了。

[此贴子已经被作者于2017-2-27 14:15编辑过]

fopen(),fread(),fseek() 有容量 (Sizes) 限制的，小于、等于 64KB，不能处理 MB 级的大小。

如果吹版能给出一篇有各种字符,也有乱码的文件,我测试一下自己搞的那段代码，看看是否可行? 代码是很早时候受kiff 版主的启发，而搞得。