请问如何实现：表单1里有一个表格grid1,数据来源于一个表，里面的数据是通过APPEN FROM写入表并通过grid1即时显示出来的，通过双击grid1第2行TEXT1事件，打开另一个表单2，并把行号2传给表单2使用？

DO FORM 命令的 WITH 参数
如果打开表单2时表数据记录指针没移动，在表单2直接对表操作就可以。

比如指针指向行号3，要操作行号2，我原来是用了do form form1 with 2命令，在表单2的init事件中加入了parameter hh，在avtivate事件中有sele 表，go hh命令,运行执行到go hh 时提示命令错误。

出错提示什么内容?
参考示例：

CREATE CURSOR tt (f1 I, f2 I)
FOR i=1 TO 10
    INSERT INTO tt VALUES (i, 2*i)
ENDFOR
GO 3
of = CREATEOBJECT("form1")
of.show(1)
RETURN

DEFINE CLASS form1 as Form
    ADD OBJECT cmd1 as CommandButton WITH Top=10,Left=10,Height=22,Caption = "form2"
    PROCEDURE init
        this.Caption = "当前记录号："+TRANSFORM(RECNO())
    ENDPROC
    PROCEDURE cmd1.Click
        of2 = CREATEOBJECT("form2",2) &&相当于 do form form2 with 2
        of2.show(1)
    ENDPROC
ENDDEFINE

DEFINE CLASS form2 as Form
    top = 100
    left = 100
    PROCEDURE init(n)
        GO n
        this.Caption = "当前记录号："+TRANSFORM(RECNO())
    ENDPROC
ENDDEFINE

或者：

CREATE CURSOR tt (f1 I, f2 I)
FOR i=1 TO 10
    INSERT INTO tt VALUES (i, 2*i)
ENDFOR
GO 3
of = CREATEOBJECT("form1")
of.show(1)
RETURN

DEFINE CLASS form1 as Form
    ADD OBJECT cmd1 as CommandButton WITH Top=10,Left=10,Height=22,Caption = "form2"
    PROCEDURE init
        this.Caption = "当前记录号："+TRANSFORM(RECNO())
    ENDPROC
    PROCEDURE cmd1.Click
        GO 2
        of2 = CREATEOBJECT("form2") &&相当于 do form form2
        of2.show(1)
    ENDPROC
ENDDEFINE

DEFINE CLASS form2 as Form
    top = 100
    left = 100
    PROCEDURE init
        this.Caption = "当前记录号："+TRANSFORM(RECNO())
    ENDPROC
ENDDEFINE

老师麻烦您帮看看，我是想把do from xjxg1 with 2 的2传给表单xjxg1中的activate事件的 go hh选择行号用，意思是go hh就是go 2。当 go hh时提示命令错误，go alltrim(hh)时提示函数参数的值或类型无效。

go alltrim(hh)时提示函数参数的值或类型无效。
改为
go hh

1、在init过程定义的hh是局部变量，init过程结束后就被释放，在执行Activate过程时hh变量不存在。
2、在init过程将hh保存在一个自定义的表单属性，在执行Activate过程时调用。
3、在Activate事件改变记录指针时要注意Activate事件的触发条件，程序运行时有可能会多次触发Activate事件。

老师麻烦您直接给出获取到2的语句，谢谢！

可以参考4楼，具体变通一下就OK