cPath=Sys(5)+Sys(2003)+"\ABC\"

lnFiles=Adir(aFile,cPath+"kqb^*.dbf" ) 

 
  Use aFile(1,1)  &&&&？？？
       
  Copy Structure To AAA           &&&另存在ABC文件夹中
  Use AAA                          
  For lnI=1 To lnFiles               
      lcStr=(aFile(lnI,1))     
    Append From '&lcStr.'        &&&合并后的文件在ABC文件夹中
  ENDFOR
  [local]1[/local]

请问如何修改命令，才能实现目的。
谢谢！

这是附件

试试用括号将文件名括起来，如：
Use (aFile(1,1))
Append From (lcStr)

 我用VFP6.0

[此贴子已经被作者于2022-7-13 05:20编辑过]

***在一个名为A123文件夹里有个程序打开文件程序PP.prg

cPath=Sys(5)+Sys(2003)+"\ABC\"

lnFiles=Adir(aFile,cPath+"kqb^*.dbf" ) 

 
  *Use aFile(1,1)  &&&&？？？
  Use (cPath+aFile(1,1))  
       
  Copy Structure To ABC\AAA           &&&另存在ABC文件夹中
  Use ABC\AAA                          
  For lnI=1 To lnFiles               
      lcStr=(aFile(lnI,1))     
    Append From '&cPath&lcStr.'        &&&合并后的文件在ABC文件夹中
  
  ENDFOR
  
  BROW

搞了一个早上，这样能达到目的，命令语句还能优化吗？

以前DOS的时候，可以用 copy a1.txt + a2.txt 这样合拼多个txt文件的，不知道DBF，能否利用这样。。。

dos copy 是低级文件函数操作，相当于VFP用 FREAD()、FWRITE()等。
VFP也可以用低级文件函数来处理相同结构的DBF：文件头块 + 数据块DBF1 +  数据块DBF2 + ......，最后要修改文件头块中的记录数值。

吹斑竹，搞个函数出来玩玩。。。

简单示例

cDefPath = ADDBS(JUSTPATH(SYS(16)))
SET DEFAULT TO (cDefPath)

CREATE TABLE dbf1 (f1 c(11), f2 I, f3 n(9,2))
INSERT INTO dbf1 VALUES ("aa", 1, 1.12)
INSERT INTO dbf1 VALUES ("bb", 2, 2.23)
USE
CREATE TABLE dbf2 (f1 c(11), f2 I, f3 n(9,2))
INSERT INTO dbf2 VALUES ("cc", 3, 3.34)
INSERT INTO dbf2 VALUES ("dd", 4, 4.45)
INSERT INTO dbf2 VALUES ("ee", 5, 5.56)
USE
dbf1 = FILETOSTR("dbf1.dbf")
dbf2 = FILETOSTR("dbf2.dbf")
nDataOffset = CTOBIN(SUBSTR(dbf1,9,2),"2rs") + 1       && 数据块偏移量
nRecords = CTOBIN(SUBSTR(dbf1,5,4),"4rs")              && dbf 记录数
nRecords = nRecords + CTOBIN(SUBSTR(dbf2,5,4),"4rs")   && 合并表记录数
dbf = STUFF(dbf1,5,4,BINTOC(nRecords,"4rs"))           && 取最前的表，修改记录数
dbf = LEFT(dbf,LEN(dbf)-1)                             && 前面的表去除文件结束标志
dbf = dbf + SUBSTR(dbf2,nDataOffset)                   && 追加最后的表（保留文件结束标志）
STRTOFILE(dbf,"dbf.dbf")                               && 保存合并的表
SELECT * FROM dbf
CLOSE TABLES ALL 
DELETE FILE dbf.dbf
DELETE FILE dbf1.dbf
DELETE FILE dbf2.dbf

谢谢吹版！