如果再来个要求，打开后不能随意复制保存，难度又增加一级

领导的这个要求有点难为人了，试想就算是不保存到本地，那你还要防止“另存为”吧，就算这个也防住了，是不是还要防止阅读的人拍照呢，
是不是有点掩耳盗铃的意思

领导不花钱哪有资格提要求？

F/S就不用考虑了，因其对远端视同本地。

可以转换成图片，内存加载

再加个水印

好吧，这样也可以了，那能否退而求其次，在文件保存后再直接打开，请问用什么命令？

看看这样能否满足要求
主机IP：192.168.1.7
主机名：abcd
主机密码：1234
共享名：temp
共享文件：test.txt
共享权限：读写

DECLARE long _strdup IN msvcrt as apiStrdup string@
DECLARE long free    IN msvcrt as apiFree long
DECLARE long WNetAddConnection2 IN mpr as apiWNetAddConnection2 string@,string@,string@,long
DECLARE long WNetCancelConnection2 IN mpr as apiWNetCancelConnection2 string@,long,long

cRemoteName = "\\192.168.1.7\temp"
IF myNetConnect(cRemoteName, "abcd", "1234")
    MODIFY FILE (cRemoteName+"\test.txt")
    apiWNetCancelConnection2(cRemoteName, 1, 1)
ENDIF
CLEAR ALL 
RETURN

FUNCTION myNetConnect(cRemoteName, cUserName, cPassWord)
    LOCAL tNR, nRet, pRemoteName
    pRemoteName = apiStrdup(cRemoteName)
    tNR = REPLICATE(0h00,4) + BINTOC(1,"4RS") + REPLICATE(0h00,12);
        + BINTOC(pRemoteName,"4RS") + REPLICATE(0h00,8)
    nRet = apiWNetAddConnection2(@tNR, cPassWord, cUserName, 1)
    IF nRet == 1219
        apiWNetCancelConnection2(cRemoteName, 1, 1)
        nRet = apiWNetAddConnection2(@stNR, cPassWord, cUserName, 1)
    ENDIF
    apiFree(pRemoteName)
    IF nRet != 0
        MESSAGEBOX("连接失败："+TRANSFORM(nRet), "提示")
    ENDIF
    RETURN (nRet == 0)
ENDFUNC

[此贴子已经被作者于2022-1-26 18:51编辑过]

吹水佬版主，您写的代码是直接存储文件在文件夹的方式，这种方式在打开的时候需要拷贝文件到本地吗？说来惭愧，使用VFP有十多年了，居然版主写的程序看不懂。如果不需要拷贝，那就可能涉及共享打开，那么，假如是EXCEL文件，能允许多人同时打开吗？当然，我只需要浏览就可以了，不需要编辑，也不允许编辑。

代码可以放到任何客户机，打开的文件是服务机的共享文件 \\192.168.1.7\temp\test.txt，不需要拷贝到本地。
示例用到 MODIFY FILE 命令，需要写权限。
用EXCEL可以只读，假设有文件 \\192.168.1.7\temp\Book1.xls
将 MODIFY FILE (cRemoteName+"\test.txt") 这句改为下面几句：
    oExcel = CREATEOBJECT("Excel.Application")
    oExcel.DisplayAlerts = 0
    oExcel.WorkBooks.Open(cRemoteName+"\Book1.xls")
    oExcel.Visible = 1