向各位学习，谢谢！

在各位老师的帮助下终于，成功了，谢谢，虽然很慢，但是毕竟成功了
CREATE CURSOR 大乐透 (红1 C(2), 红2 C(2), 红3 C(2),红4 C(2),红5 C(2),兰1 C(2),兰2 C(2),期号 C(5))
lcUrl = "https://webapi.
oHTTP=NEWOBJECT("MSXML2.XMLHTTP")
oHTTP.Open("GET", lcUrl, .F.)
oHTTP.SETREQUESTHEADER("Content-Type", "text/html;charset=UTF-8")
oHTTP.Send()
lcText = STRCONV(oHTTP.ResponseBody, 11)
lmText = STREXTRACT(lcText,'lotteryUnsortDrawresult":"','","matchList')
lyText = STREXTRACT(lcText,',"lotteryDrawNum":"','","lotteryDrawResult":"')
lstext = OCCURS("lotteryDrawNum", lcText)
? lmText ,lyText ,lstext
FOR lnj = 1 TO OCCURS("lotteryDrawNum", lcText)
    lyText = STREXTRACT(lcText,',"lotteryDrawNum":"','","lotteryDrawResult":"', lnj)
    lmText = STREXTRACT(lcText,'lotteryUnsortDrawresult":"','","matchList', lnj)
   h1 = Substr(lmText ,1,2)
   h2 = Substr(lmText ,4,2)
   h3 = Substr(lmText ,7,2)
   h4 = Substr(lmText ,10,2)
   h5 = Substr(lmText ,13,2)
   l1 = Substr(lmText ,16,2)
   l2 = Substr(lmText ,19,2)
   q1 = Substr(lyText ,1,5)
   INSERT INTO 大乐透 VALUES (h1,h2,h3,h4,h5,l1,l2,q1)
  ENDFOR

[此贴子已经被作者于2021-6-1 20:47编辑过]

另外，各位老师，没有找到使用第几套球的采集入口，麻烦各位老师再看看，谢谢.

应该是这个字段：lotteryEquipmentCount

看下ALINES()的用法

测试结果的确有点慢，比对了一下：
耗时：254秒

CREATE CURSOR 大乐透 (红1 C(2), 红2 C(2), 红3 C(2),红4 C(2),红5 C(2),兰1 C(2),兰2 C(2),期号 C(5))
lcUrl = "https://webapi./gateway/lottery/getHistoryPageListV1.qry?gameNo=85&provinceId=0&pageSize=0"
oHTTP=NEWOBJECT("MSXML2.XMLHTTP")
oHTTP.Open("GET", lcUrl, .F.)
oHTTP.SETREQUESTHEADER("Content-Type", "text/html;charset=UTF-8")
oHTTP.Send()
lcText = oHTTP.ResponseText

t1 = SECONDS()
FOR lnj = 1 TO OCCURS("lotteryDrawNum", lcText)
    lyText = STREXTRACT(lcText,',"lotteryDrawNum":"','"', lnj)
    lmText = STREXTRACT(lcText,'lotteryUnsortDrawresult":"','"', lnj)
    h1 = Substr(lmText ,1,2)
    h2 = Substr(lmText ,4,2)
    h3 = Substr(lmText ,7,2)
    h4 = Substr(lmText ,10,2)
    h5 = Substr(lmText ,13,2)
    l1 = Substr(lmText ,16,2)
    l2 = Substr(lmText ,19,2)
    INSERT INTO 大乐透 VALUES (h1,h2,h3,h4,h5,l1,l2,lyText)
ENDFOR
? SECONDS() - t1 && 254秒

用JS代码相对也只要1秒多点，真有点意外，大家测试一下：

CREATE CURSOR 大乐透 (红1 C(2), 红2 C(2), 红3 C(2),红4 C(2),红5 C(2),兰1 C(2),兰2 C(2),期号 C(5))
cUrl = "https://webapi./gateway/lottery/getHistoryPageListV1.qry?gameNo=85&provinceId=0&pageSize=0"
oHttp = CREATEOBJECT("MSXML2.XMLHTTP")
oHttp.Open("GET", cUrl, .F.)
oHttp.Send()

t1 = SECONDS()

jsCode = 'var data=' + oHttp.responseText + ';' +;
         'var list=data["value"]["list"];' +;
         'function getList(n,name){return list[n][name];}'
oSC = CREATEOBJECT("ScriptControl")
oSC.Language = "JavaScript"
oSC.AddCode(jsCode)
FOR i=0 TO oSC.eval('list.length')-1
    lyText = oSC.run("getList",i,"lotteryDrawNum")
    lmText = oSC.run("getList",i,"lotteryUnsortDrawresult")
    h1 = Substr(lmText ,1,2)
    h2 = Substr(lmText ,4,2)
    h3 = Substr(lmText ,7,2)
    h4 = Substr(lmText ,10,2)
    h5 = Substr(lmText ,13,2)
    l1 = Substr(lmText ,16,2)
    l2 = Substr(lmText ,19,2)
    INSERT INTO 大乐透 VALUES (h1,h2,h3,h4,h5,l1,l2,lyText)
ENDFOR
? SECONDS() - t1 && 1.6秒

楼主：300秒
吹版：0.9秒

CLEAR 
CREATE CURSOR 大乐透 (红1 C(2), 红2 C(2), 红3 C(2),红4 C(2),红5 C(2),兰1 C(2),兰2 C(2),期号 C(5), 球具 N(1))
cUrl = "https://webapi./gateway/lottery/getHistoryPageListV1.qry?gameNo=85&provinceId=0&pageSize=0&" + SUBSTR(SYS(2015), 2)
t1 = SECONDS()
oHttp = CREATEOBJECT("MSXML2.XMLHTTP")
oHttp.Open("GET", cUrl, .F.)
oHttp.Send()
lcText = oHttp.ResponseText
? "下载数据：", SECONDS() - t1
t1 = SECONDS()
lcText = STREXTRACT(lcText, '{"list":[{"', '')
ALINES(laText, lcText, '{}},{"')
FOR ln1 = 1 TO ALEN(laText, 1)
    ALINES(laStr, laText[ln1], '},{"', '":', ',"', '[{"', '}]')
    ALINES(laHm, &laStr[14], SPACE(1))
    INSERT INTO 大乐透 VALUES (laHm[1], laHm[2], laHm[3], laHm[4], laHm[5], laHm[6], laHm[7], &laStr[12], &laStr[20])
ENDFOR
? "解析数据：", SECONDS() - t1 && 0.6秒
BROWSE 

[此贴子已经被作者于2021-6-1 23:19编辑过]

STREXTRACT()在解析这种大块头JSON数据中速度确实慢，ALINES()速度则飞快，建议大家以后解析类似这种大块头的文本，使用ALINES()函数。ALINES()是解析文本字符的利器。