VB如何读取word中表格第一列、第二列内容？ - VB6论坛

楼主

已结贴√ 问题点数：20 回复次数：6

VB如何读取word中表格第一列、第二列内容？

搜索更多相关主题的帖子: 读取　 word　表格　一列　内容　

第 2 楼

得分:20

回复楼主 xingming022

程序代码：

Option Explicit

Dim str1 As String
Dim str2 As String

Private Sub Command1_Click()
  Dim myword As Object, mydocument As Object, mytable As Object
  Set myword = CreateObject("Word.Application") '创建word对象
  myword.Visible = True
  Set mydocument = myword.Documents.Open(App.Path & "\123.docx")
  
  Dim i As Byte
  Dim j As Byte
  For i = 1 To mydocument.Tables.Count
      Set mytable = mydocument.Tables(i)
      For j = 1 To mytable.Rows.Count
          str1 = mytable.Cell(j, 1).Range
          str1 = Left(str1, Len(str1) - 2)
          Print str1
          str2 = mytable.Cell(j, 2).Range
          str2 = Left(str2, Len(str2) - 2)
          Print str2
      Next
  Next
End Sub

窗体添加一个命令按钮，AutoRedraw属性为True

不经历千百遍的调试，怎能体会成功时那一刹那的喜悦。

第 3 楼

得分:0

回复 2楼 wufuzhang

非常感谢，如果是123.doc 这个文件已经打开了该怎么操作？

第 4 楼

得分:0

回复 3楼 xingming022

程序代码：

Option Explicit

Dim str1 As String
Dim str2 As String

Private Sub Command1_Click()
On Error Resume Next
  Dim k As Integer
  Dim filepath As String
  Dim myword As Object, mydocument As Object, mytable As Object
  
  
  filepath = App.Path & "\123.docx"
  If Dir(filepath) <> "" Then
     Name filepath As App.Path & "\1232.docx"
  End If
  If Err.Number <> 0 Then
     Print "文件打开了"
     Set myword = GetObject(, "Word.Application")
     For Each mydocument In myword.documents
         k = k + 1
         If mydocument.FullName = filepath Then
            Exit For
         End If
     Next
     Set mydocument = myword.documents(k)
  Else
     Print "文件没打开"
     Name App.Path & "\1232.docx" As filepath
     Set myword = CreateObject("Word.Application") '创建word对象
     myword.Visible = True
     Set mydocument = myword.documents.Open(filepath)
  End If
  

 
  
  Dim i As Byte
  Dim j As Byte
  For i = 1 To mydocument.Tables.Count
      Set mytable = mydocument.Tables(i)
      For j = 1 To mytable.Rows.Count
          str1 = mytable.Cell(j, 1).Range
          str1 = Left(str1, Len(str1) - 2)
          Print str1
          str2 = mytable.Cell(j, 2).Range
          str2 = Left(str2, Len(str2) - 2)
          Print str2
      Next
  Next
End Sub