vfp如何删除文件并清空回收站 - VFP论坛

楼主

已结贴√ 问题点数：20 回复次数：9

vfp如何删除文件并清空回收站

用如下代码删除文件名文件夹后，都进回收站了，请问如何直接删除，不进回收站呢？

程序代码：

***删除文件夹
**调用格式deldirapiover('d:\tmp')
PARAMETERS cPath
cPath=ALLTRIM(cPath)
cPath=LEFT(cPath,LEN(cPath)-IIF(RIGHT(cPath,1)=='\',1,0))
DECLARE LONG GetProcessHeap  IN Kernel32
DECLARE LONG HeapAlloc       IN Kernel32 LONG, LONG, LONG
DECLARE LONG HeapFree        IN Kernel32 LONG, LONG, LONG
DECLARE LONG HeapDestroy     IN Kernel32 LONG
DECLARE LONG SHFileOperation IN Shell32 STRING@
** 删除文件，包括删除整个文件夹。
LOCAL hHeap, pFileName, stFileOp, bRet
cFileName = cPath + 0h0000
bRet = .T.
TRY 
    hHeap = GetProcessHeap()
    pFileName = HeapAlloc(hHeap, 8, LEN(cFileName))
    SYS(2600, pFileName, LEN(cFileName), cFileName)
    stFileOp = REPLICATE(0h00, 4) + BINTOC(3, "4RS") + BINTOC(pFileName, "4RS") + REPLICATE(0h00, 4) + BINTOC(80, "2RS") + REPLICATE(0h00, 12)
    bRet = (SHFileOperation(@stFileOp) == 0)
CATCH
    bRet = .F.
ENDTRY
HeapFree(hHeap, 1, pFileName)
HeapDestroy(hHeap)
CLEAR DLLS
RETURN bRet

搜索更多相关主题的帖子: vfp　删除　文件　 LONG　Kernel32　

第 2 楼

得分:0

网上查到的资料：回收站是Shell的东西，要用Shell操作

一：gpedit.msc：设置直接删除文件
进入开始菜单，选择“运行...”，输入“gpedit.msc”；
在弹出的对话框中，选择用户设置，管理模板，Windows 组件，Windows Explorer，找到“不要将删除的文件移送到回收站”的选项。开启这个选项。
二：“回收站”，“属性”，“删除时不将文件移入回收站而是彻底删除”
三：shift+del
四：“回收站”“属性”“全局”标签，把表示回收站的容量的滑块拖到最左侧，变为“0”时。

[此贴子已经被作者于2018-9-1 19:24编辑过]

坚守VFP最后的阵地

第 3 楼

得分:5

#Define SHERB_NOCONFIRMATION = 0x00000001
#Define SHERB_NOPROGRESSUI   = 0x00000002
#Define SHERB_NOSOUND        = 0x00000004
Declare Integer SHEmptyRecycleBin In shell32 ;
    INTEGER HWnd,;
    STRING  pszRootPath,;
    LONG    dwFlags

=SHEmptyRecycleBin(0, Null, 0x00000002)  && OK

团队红星二锅头,队长王猛,领队李冲,顾问杨伟,副队张挺,外联马彪,内勤韩秀,人事顾闯,财务赵魁,后勤周强

第 4 楼

得分:0

@hyswcyh，红星二锅头，可以达到要求，但要出现确认对话框的。

第 5 楼

得分:15

以下是引用hyswcyh在2018-9-1 18:18:19的发言：

stFileOp = REPLICATE(0h00, 4) + BINTOC(3, "4RS") + BINTOC(pFileName, "4RS") + REPLICATE(0h00, 4) + BINTOC(80, "2RS") + REPLICATE(0h00, 12)

试试将其中的 BINTOC(80, "2RS") 改为 BINTOC(0x90, "2RS")