想在用vfp打开的word文档关闭后执行下一条命令，如何判断WORD文档是否已被关闭？

[此贴子已经被作者于2018-5-25 22:34编辑过]

是怎样打开word文档，代码？

*打开word文档代码
DECLARE INTEGER ShellExecute IN shell32.DLL INTEGER HWND,;
STRING lpszOP, ;
STRING lpszFile, ;
STRING lpszParams, ;
STRING lpszDir, ;
INTEGER fsshowcmd
DECLARE INTEGER GetDesktopWindow IN win32api
HWND = GetDesktopWindow()
lpszOP = "open"
* 指定要打开的文件名
lpszFile ="rhtbzy.doc"
lpszParams = ""
lpszDir = lpszFile
fsshowcmd =1
* 执行ShellExecute命令
LNRETURN = ShellExecute(HWND, lpszOP,lpszFile, lpszParams, lpszDir,fsshowcmd)

[此贴子已经被作者于2018-5-26 16:06编辑过]

用外部进程打开的文件，只能用独占方式打开这个文件，如果打开失败，说明还在使用中。
可以试试用 WinAPI CreateFile()，将第3个参数 dwShareMode 设 0。

感谢吹水佬，我没用过WinAPI CreateFile()，还是没解决...

Win10环境用CreateFile没试成，用OpenFile试试：
注意：测试时文件名是用完整路径

DECLARE LONG OpenFile IN Kernel32 STRING@, STRING@, LONG
DECLARE LONG CloseHandle IN Kernel32 LONG

DECLARE INTEGER ShellExecute IN shell32.DLL INTEGER HWND,;
STRING lpszOP, ;
STRING lpszFile, ;
STRING lpszParams, ;
STRING lpszDir, ;
INTEGER fsshowcmd
DECLARE INTEGER GetDesktopWindow IN win32api
HWND = GetDesktopWindow()
lpszOP = "open"
* 指定要打开的文件名
lpszFile ="C:\TEMP\test.doc"
**lpszFile ="rhtbzy.doc"
lpszParams = ""
lpszDir = lpszFile
fsshowcmd =1
* 执行ShellExecute命令
LNRETURN = ShellExecute(HWND, lpszOP, lpszFile, lpszParams, lpszDir, fsshowcmd)

DO WHILE isFOpen(lpszFile)
    INKEY(1)
ENDDO
**INKEY(3)
DO WHILE !isFOpen(lpszFile)
    INKEY(1)
ENDDO
? "文件已经关闭"
RETURN
 
FUNCTION isFOpen(cFileName)
    LOCAL hFile, st
    st = REPLICATE(0h00,136)
    hFile = OpenFile(@cFileName, @st, 0x10)
    IF (hFIle != -1)
        CloseHandle(hFile)
    ENDIF
    RETURN hFIle != -1
ENDFUNC

谢谢吹水佬！我在win7下试了，能用。

不错，备用。