很多时候我需要查询到物料的最新价格，其中包含有采购价、存货价、销售价、市场价等等很多很多。…………


没一张表我都会用同样的代码来实现查询功能。代码如下：

select * from 存货表 t1 rgiht join (select max(日期） 日期,料号 from 存货表 group by 2 ) t2 on t1.日期=t2.日期 and t1.料号=t2.料号



 

每次来一张新的表格，我都需要重复的编写这样的代码，有没有一种方法可以实现让我运行某一个小的程序，自动获取到这张表的最新价格。


可以变动的字段有：表的名字可能会有变动（例如：存货表、采购表、发票表、订单表等等）。日期字段也会改成不同的名字（例如：日期、期间、年等等）。其他的都无所谓。


如果程序可以直接写成为：   

do  查询（价格表，日期字段，料号）

然后可以实现查询价格表里里面，日期最大的时候的详细信息。查询的理论是：“找到每一颗物料的最新交易价格。”

[此贴子已经被作者于2018-5-4 22:26编辑过]

这个应该不难，我也常写几十行的小程序来实现某个功能。但你写的我看不懂，因为我不熟悉select语句。

select * from 存货表 t1 ;
inner join (select max(日期） as 日期,料号 from 存货表 group by 料号 ) t2 on t1.日期=t2.日期 and t1.料号=t2.料号;
where t1.料号 = allt(thisform.text1.value) &&

收到的鲜花

• hyz00001 于 2018-05-05 12:09 送鲜花  1朵   附言：谢谢解答

谢谢你的解答，一个一个的查询，我自己能搞定，需要的是知道怎么样可以编写一段子程序，然后通过运行子程序来获得新的表（新表内容为物料的最新交易价格。）而且这个子程序是一劳永逸的，可以实现不同表的最新交易价格查询。

*!* 测试数据
SET CENTURY ON
SET DATE YMD
CREATE CURSOR tt(序号 i,日期 d,物料 c(20),价格 n(10,2))

INSERT INTO tt(序号,日期,物料,价格) VALUES (1,{^2018-05-01},"电脑01",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (2,{^2018-05-02},"电脑01",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (3,{^2018-05-03},"电脑01",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (4,{^2018-05-01},"电脑02",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (5,{^2018-05-04},"电脑02",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (6,{^2018-05-06},"电脑02",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (7,{^2018-05-02},"电脑03",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (8,{^2018-05-05},"电脑03",INT(RAND()*10))
INSERT INTO tt(序号,日期,物料,价格) VALUES (9,{^2018-05-06},"电脑03",INT(RAND()*10))

* BROWSE



LOCAL tmp

tmp = GetMax("TT","日期","物料")
IF !EMPTY(tmp)
   SELECT (tmp)
   BROWSE
ELSE
   MESSAGEBOX("参数有问题")   
ENDIF
   

*!* 调用函数，参数正常时，返回非空值的临时表名称
FUNCTION GetMax(cTableName,cDateField,cGroupField)
 LOCAL tmp_TableName,cSql
 tmp_TableName = ""
 cSql = ""
 *!* 检测源表
 IF TYPE("cTableName") = "C"  AND USED(cTableName) AND TYPE("cDateField") = "C" AND TYPE("cGroupField") = "C"
    tmp_TableName = LOWER("tmp"+SYS(2015))
    TEXT TO cSql TEXTMERGE NOSHOW PRETEXT 4
     SELECT t1.* FROM <<cTableName>> AS t1 ;
      RIGHT JOIN (SELECT MAX(<<cDateField>>) AS <<cDateField>> ,<<cGroupField>> FROM <<cTableName>> GROUP BY <<cGroupField>>) AS t2 ;
      ON t1.<<cGroupField>> = t2.<<cGroupField>> and t1.<<cDateField>> = t2.<<cDateField>> ;
      INTO CURSOR <<tmp_TableName>> READWRITE ;
      ORDER BY t1.<<cGroupField>>
    ENDTEXT
*   messagebox(cSql) &&观察生成的SQL语句对不对
    EXECSCRIPT(cSql)
 ENDIF
 RETURN tmp_TableName
ENDFUNC

[此贴子已经被作者于2018-5-5 14:04编辑过]

只有想不到，没有做不到

学习啦，谢谢！

就是这个效果，你是怎么样做到的，真厉害。

*  messagebox(cSql) &&观察生成的SQL语句对不对
你看看输出,是不是你要的就可以了,然后,慢慢1条条看


*也可以改成这样
*!* 调用函数，参数正常时，返回非空值的临时表名称
FUNCTION GetMax(cTableName,cDateField,cGroupField)
  LOCAL tmp_TableName,cSql
  tmp_TableName = ""
  cSql = ""
  *!* 检测源表
 IF TYPE("cTableName") = "C"  AND USED(cTableName) AND TYPE("cDateField") = "C" AND TYPE("cGroupField") = "C"
     tmp_TableName = LOWER("tmp"+SYS(2015))
     cSql = "SELECT t1.* FROM " + cTableName + " AS t1"
     cSql = cSql + " RIGHT JOIN (SELECT MAX(" + cDateField + ") AS " + cDateField + "," + cGroupField + " FROM " + cTableName + " GROUP BY " + cGroupField + ") AS t2"
     cSql = cSql + " ON t1." + cGroupField + "= t2."+ cGroupField +" and t1." + cDateField + " = t2." + cDateField
     cSql = cSql + " INTO CURSOR " + tmp_TableName +" READWRITE"
     cSql = cSql + " ORDER BY t1." + cGroupField

 *   messagebox(cSql) &&观察生成的SQL语句对不对
    EXECSCRIPT(cSql)
  ENDIF
  RETURN tmp_TableName
 ENDFUNC

[此贴子已经被作者于2018-5-7 15:32编辑过]