请问如何用代码修改注册表，现实开机自启；以及如何关闭开机自启。（比如程序：e:\xs.exe）

注册表的常用Run键
......\SOFTWARE\Microsoft\Windows\CurrentVersion\Run
XP的系统菜单还有个启动（startup）目录：C:\Documents and Settings\Administrator\「开始」菜单\程序\启动

#define HKEY_LOCAL_MACHINE    2147483646
*在WindowsAPI编程中，HKEY—LOCAL—MACHINE 被预置为0x80000002，即十进制的－2147483646
clear menu all
set sysme off
Declare Integer RegSetValue In Win32API integer nHkey,STRING cSubKey, integer dwType,string@ lpDatainteger,integer@ count
newValue="e:\小精灵\小精灵.exe"
i=len(newValue)
nResult=RegSetValue(HKEY_LOCAL_MACHINE,"Software\Microsoft\windows\CurrentVersion\run",1,@newvalue,@i)
if nResult#0
wait wind "修改注册表失败！"
endi

&&以上是收集自网上的代码，没测试成功。帮助分析一下！

简单试了一下（XP、WIN10）
** HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run
#DEFINE HKEY_CURRENT_USER    -2147483647

DECLARE LONG RegOpenKey IN Advapi32 LONG, STRING@, LONG@
DECLARE LONG RegCloseKey IN Advapi32 LONG
DECLARE LONG RegSetValueEx IN Advapi32 LONG, STRING@, LONG, LONG, STRING@, LONG

LOCAL cFileName, hKey
cFileName = "C:\temp\test.exe"
hKey = 0
IF RegOpenKey(HKEY_CURRENT_USER, "Software\Microsoft\Windows\CurrentVersion\Run", @hKey)==0
    RegSetValueEx(hKey, "test", 0, 1, cFileName, LEN(cFileName))
    RegCloseKey(hKey)
ENDIF

设置后，如何取消开机自启，也就是复原。

取消可以用RegDeleteValue直接删除掉
** HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run
#DEFINE HKEY_CURRENT_USER    -2147483647

DECLARE LONG RegOpenKey IN Advapi32 LONG, STRING@, LONG@
DECLARE LONG RegCloseKey IN Advapi32 LONG
DECLARE LONG RegSetValueEx IN Advapi32 LONG, STRING@, LONG, LONG, STRING@, LONG
DECLARE LONG RegDeleteValue IN Advapi32 LONG, STRING@

**    IF myStartup("test", "C:\temp\test.exe")
**        ? "设置成功"
**    ENDIF

IF myStartup("test")
    ? "取消成功"
ENDIF


FUNCTION myStartup(cValName, cFileName)
    LOCAL hKey, ret
    hKey = 0
    ret = RegOpenKey(HKEY_CURRENT_USER, "Software\Microsoft\Windows\CurrentVersion\Run", @hKey)==0
    IF ret
        IF !EMPTY(cFileName)
            ret = FILE(cFileName)
            IF ret
                ret = RegSetValueEx(hKey, cValName, 0, 1, cFileName, LEN(cFileName))==0
            ENDIF
        ELSE
            ret = RegDeleteValue(hKey, cValName)==0
        ENDIF
        RegCloseKey(hKey)
    ENDIF
    RETURN ret
ENDFUNC

这个不错！用得到！