function testjpg(a,nwidth,nheight)
lcImageName=a
Declare Integer GdipLoadImageFromFile In GDIPlus.Dll String wFilename, Integer @nImage
Declare Integer GdipGetImageWidth In GDIPlus Integer img,Integer @ imgwidth
Declare Integer GdipGetImageHeight In GDIPlus Integer img,Integer @ imgheight
Declare Integer GdipDisposeImage In GDIPlus.Dll Long nativeImage
Store 0 To nImage,nWidth,nHeight
GdipLoadImageFromFile(Strconv(lcImageName+Chr(0),5),@nImage)
GdipGetImageWidth(nImage,@nWidth)
GdipGetImageHeight(nImage,@nHeight)
GdipDisposeImage(nImage)
return nWidth
return nHeight
endfunction

我使用的时候是这样的
testjpg(getfile("jpg"),nw,nh)
?nw
?nh
哪里不对呢？

nw = 0
nh = 0
testjpg(getfile("jpg"), @nw, @nh)
?nw
?nh

return nWidth
return nHeight &&这句有效吗？
这两句不要

clear
local nw,nh
testjpg(getfile("jpg"),@nw,@nh)
?nw,nh
function testjpg(a,nwidth,nheight)
lcImageName=a
Declare Integer GdipLoadImageFromFile In GDIPlus.Dll String wFilename, Integer @nImage
Declare Integer GdipGetImageWidth In GDIPlus Integer img,Integer @ imgwidth
Declare Integer GdipGetImageHeight In GDIPlus Integer img,Integer @ imgheight
Declare Integer GdipDisposeImage In GDIPlus.Dll Long nativeImage
Store 0 To nImage,nWidth,nHeight
GdipLoadImageFromFile(Strconv(lcImageName+Chr(0),5),@nImage)
GdipGetImageWidth(nImage,@nWidth)
GdipGetImageHeight(nImage,@nHeight)
GdipDisposeImage(nImage)
endfunc

*获取图像文件的宽和高（像素）
cImg = Getpict()   && 获取 bmp, jpg, gif  
   
xImgObj = LoadPicture(cImg)  
With xImgObj  
    lnWidth = Int(.Width/26.458)  
    lnHeight = Int(.Height/26.458)  
Endwith  
   
Messagebox("宽度 = " + Transform(lnWidth) + "(像数)" + Chr(13) + ;  
    "高度 = " + Transform(lnHeight) + "(像数)")

不需要return啊？

op = CREATEOBJECT("Image")
op.Picture = GETPICT()
? "Width  : ", op.Width
? "Height : ", op.Height

这么简单。。。

5 楼的化简也可以这么简单：

xImgObj = LoadPicture(Getpict())
? "宽度 : ", Int(xImgObj.Width/26.458)
? "高度 : ", Int(xImgObj.Height/26.458)