求destroy和unload的区别！

destroy是对象被释放时触发，顺序是“先父后子”。
unload是表单或表单集被释放时触发，顺序是“先子后父”。

例子是：一个表单上　放一个退出按钮

事件的顺序是　　按钮的init ——表单的init——表单的load——按钮的load
然后 read events

等用户按了退出  

按钮的unload ——表单的unload——表单的destroy——按钮的destroy

这几个事件   是这顺序吗？

按钮默认是没有load、unload事件。

可以这样检测：

CREATE CURSOR tt (ff C(20))
of = CREATEOBJECT("Form1")
of.show(1)
BROWSE


DEFINE CLASS Form1 as Form 
    ADD OBJECT cmd as CommandButton WITH top=100,left=100
    
    PROCEDURE Init
        INSERT INTO tt VALUES ("Form Init")
    ENDPROC

    PROCEDURE Load
        INSERT INTO tt VALUES ("Form Load")
    ENDPROC

    PROCEDURE Destroy
        INSERT INTO tt VALUES ("Form Destroy")
    ENDPROC

    PROCEDURE Unload
        INSERT INTO tt VALUES ("Form Unload")
    ENDPROC

    PROCEDURE cmd.Init
        INSERT INTO tt VALUES ("Button Init")
    ENDPROC

    PROCEDURE cmd.Destroy
        INSERT INTO tt VALUES ("Button Destroy")
    ENDPROC

    PROCEDURE cmd.Load
        INSERT INTO tt VALUES ("Button Load")
    ENDPROC

    PROCEDURE cmd.Unload
        INSERT INTO tt VALUES ("Button Unload")
    ENDPROC
ENDDEFINE

收藏  这几个事件顺序    总被我弄乱套

不仅仅是时序那么简单的