在数据库的photo字段中有一个大图，现因为要用水晶报表打印照片字段，因此需要一个小图，我打算将它存在sphoto字段中。我现将photo中的大图按比例缩小后放在picturebox中，请问怎样将其存入sphoto中？

请参看：
[转]VB 图片转换为Byte()和从Byte()中读取图片的捷径https://bbs.bccn.net/thread-248470-1-1.html

我照您说的做了,不行啊!sphoto字段仍然显示不出来.
代码如下:
Dim PBag As New PropertyBag
PBag.WriteProperty "Picture", Picture2.Picture
Adodc1.Recordset.Fields("sphoto") = PBag.Contents
Adodc1.Recordset.update
Adodc1.Refresh
另外按您的第二种方法,只能将电脑中有存储路径的文件存到数据库中,而不能将picturebox中的图片存入,好象也不能用.
麻烦问一下,还有别的方法没有?

[ 本帖最后由 冰雪清风 于 2010-1-10 15:23 编辑 ]

存图片的字段类型是什么？

存图片的字段类型是image

而不能将picturebox中的图片存入,好象也不能用.

picturebox 载入的图像使用 它的 picture 属性取得图像
绘制，复制的图像，使用 它的 image 属性取得图像。

这个是把文件数据储存到数据库里。
数据库里存储图片的字段类型是OLE，但是，我怎么找都找不到例子。
呃！是找到了，但那是NET框架的。
那就只好用流了。

这个image是什么类型？
ms access 里没有这个数据类型吧。
比如ole、long byte之类的。

[ 本帖最后由 bczgvip 于 2010-1-11 23:50 编辑 ]

我把代码改为:
   PBag.WriteProperty "image", Picture2.Image
可是还是无法显示.怎么回事?
另,我的数据库是SQL.
7楼您的方法我看了一下,好象是从本机路径上取得图像,再存入数据库中,而我需要从VB的picturebox中取得图像.不知用流的方法能解决吗?

[ 本帖最后由 冰雪清风 于 2010-1-12 11:28 编辑 ]

看起来，楼主是想要将编辑过的图片存入数据库。这时候图片不是从文件路径中加载的了，对吧？

我给你写了一个例子。你参考一下：（代码在下一楼）

一）建一个测试的表：
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[TmpPic]') and OBJECTPROPERTY(id, N'IsUserTable') = 1)
drop table [dbo].[TmpPic]
GO

CREATE TABLE [dbo].[TmpPic] (
    [id] [int] IDENTITY (1, 1) NOT NULL ,
    [width] [numeric](18, 0) NULL ,
    [height] [numeric](18, 0) NULL ,
    [photo] [image] NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
GO

二）VB6中，新建一个工程，在Form1上画 二个按钮控件，二个Picturebox控件,一个CommonDialog控件，所有属性均采用默认值

三）将下一楼的代码复制到窗体Form1的窗体代码中

四）按下F5键运行。

本测试程序时注意事项在楼上

Dim bit1() As Byte
Private Declare Function GetObject Lib "gdi32" Alias "GetObjectA" (ByVal hObject As Long, ByVal nCount As Long, lpObject As Any) As Long
Private Declare Function GetBitmapBits Lib "gdi32" (ByVal hBitmap As Long, ByVal dwCount As Long, lpBits As Any) As Long
Private Declare Function SetBitmapBits Lib "gdi32" (ByVal hBitmap As Long, ByVal dwCount As Long, lpBits As Any) As Long
Private Type BITMAP
  bmType As Long
  bmWidth As Long
  bmHeight As Long
  bmWidthBytes As Long
  bmPlanes As Integer
  bmBitsPixel As Integer
  bmBits As Long
End Type

Function getbit(ByVal hbmp As Long, ByRef bit() As Byte)
Dim picinfo As BITMAP
GetObject hbmp, Len(picinfo), picinfo
ReDim bit(1 To picinfo.bmHeight * picinfo.bmWidth * 4)
GetBitmapBits hbmp, UBound(bit), bit(1)
End Function

Private Sub Command1_Click() '保存图片
Dim Conn As New ADODB.Connection
Dim Rs As New ADODB.Recordset
Conn.ConnectionString = "这里写上连接你的SQLSERVER数据库的代码"
Conn.Open
Rs.Open "select * from [TmpPic]", Conn, 1, 3
Rs.AddNew
   getbit Picture1.Image, bit1()
   Rs("width") = Picture1.Width'记录下图片的宽度
   Rs("height") = Picture1.Height'记录下图片的高度
   Rs("photo").AppendChunk bit1()
Rs.Update

Rs.Close
Conn.Close
Set Rs = Nothing
Set Conn = Nothing
End Sub

Private Sub Command2_Click() '显示图片
Dim Conn As New ADODB.Connection
Dim Rs As New ADODB.Recordset
Conn.ConnectionString = "这里写上连接你的SQLSERVER数据库的代码"
Conn.Open
Rs.Open "select * from [TmpPic]", Conn, 1, 1
  ReDim bit1(1)
  Picture2.Width = Rs("width")
  Picture2.Height = Rs("height")
  bit1 = Rs("photo").GetChunk(Rs("photo").ActualSize)
  SetBitmapBits Picture2.Image, UBound(bit1), bit1(0)
  Picture2.Refresh
Rs.Close
Conn.Close
Set Rs = Nothing
Set Conn = Nothing

End Sub

Private Sub Form_Load()
Command1.Caption = "保存图片"
Command2.Caption = "读取图片"
End Sub

Private Sub Picture1_Click() '给Pictrue1加载一幅图片
CommonDialog1.ShowOpen
Picture1.Picture = LoadPicture(CommonDialog1.FileName)
End Sub