有没有办法用VFP转换EXCEL表格？ - VFP论坛

smart921

等　级：新手上路
帖　子：107
专家分：9
注　册：2010-8-8
结帖率：86.96%

楼主

已结贴√ 问题点数：30 回复次数：6

有没有办法用VFP转换EXCEL表格？

如何将下列表格
A公司
    1车间
        班组A
            刘**
            李**
        班组B
            殷**
            杨**
    2车间
        班组A
            朱**
            张**
        班组B
            曹**
            占**
B公司
    1车间
        班组A
            刘**
            吕**
        班组B
            叶**
            杨**
    2车间
        班组A
            朱**
            鹏**
        班组B
            曹**
            林**
转换为下列格式

单位    车间    班组    姓名
A公司    1车间    班组A    刘**
A公司    1车间    班组A    李**
A公司    1车间    班组B    殷**
A公司    1车间    班组B    杨**
A公司    2车间    班组A    朱**
A公司    2车间    班组A    张**
A公司    2车间    班组B    曹**
A公司    2车间    班组B    占**
B公司    1车间    班组A    刘**
B公司    1车间    班组A    吕**
B公司    1车间    班组B    叶**
B公司    1车间    班组B    杨**
B公司    2车间    班组A    朱**
B公司    2车间    班组A    鹏**
B公司    2车间    班组B    曹**
B公司    2车间    班组B    林**

测试.rar (1.73 KB)

搜索更多相关主题的帖子: 转换　公司　 VFP　EXCEL　表格　

2020-10-22 20:01

吹水佬

等　级：版主
威　望：432
帖　子：10064
专家分：41463
注　册：2014-5-20

第 3 楼

得分:15

程序代码：

cDefaultPath = ADDBS(JUSTPATH(SYS(16)))
SET DEFAULT TO (cDefaultPath)

oExcel = CREATEOBJECT("Excel.Application")
oExcel.DisplayAlerts = 0
oExcel.WorkBooks.Open(cDefaultPath+"测试.xls")
oExcel.ActiveWorkBook.SaveAs(cDefaultPath+"tmp.txt", -4158)
oExcel.Quit

CREATE CURSOR tt (f1 C(10),f2 C(10),f3 C(10),f4 C(10))
CREATE CURSOR tmp (f1 C(10),f2 C(10),f3 C(10),f4 C(10))
APPEND FROM tmp.txt DELIMITED WITH TAB 
STORE "" TO m1,m2,m3
SCAN 
    IF !EMPTY(f1) AND m1!=f1
        m1 = f1
    ENDIF
    IF !EMPTY(f2) AND m2!=f2
        m2 = f2
    ENDIF
    IF !EMPTY(f3) AND m3!=f3
        m3 = f3
    ENDIF
    IF !EMPTY(f4)
        INSERT INTO tt VALUES (m1,m2,m3,tmp.f4)
    ENDIF
ENDSCAN

SELECT * FROM tt

2020-10-22 21:52

sdta

来　自：江苏省连云港市
等　级：版主
威　望：323
帖　子：9621
专家分：26174
注　册：2012-2-5

第 5 楼

得分:15

oExcel = CREATEOBJECT("Excel.Application")
oExcel.WorkBooks.Open(SYS(5)+SYS(2003)+"\测试.xls")
oExcel.DisplayAlerts = .F.
oExcel.ActiveWorkbook.Saveas(SYS(5)+SYS(2003)+"\cs.txt", -4158)
oExcel.Quit
RELEASE oExcel
CREATE CURSOR cs (f1 C(10),f2 C(10),f3 C(10),f4 C(10))
APPEND FROM cs.txt DELIMITED WITH TAB
GO top
m1 = f1
m2 = f2
m3 = f3
SCAN
    IF EMPTY(f1)
        REPLACE f1 WITH m1
    ENDIF
    IF EMPTY(f2)
        REPLACE f2 WITH m2
    ENDIF
    IF EMPTY(f3)
        REPLACE f3 WITH m3
    ENDIF
    m1 = f1
    m2 = f2
    m3 = f3
ENDSCAN
SELECT * FROM cs WHERE !EMPTY(f4)

坚守VFP最后的阵地

2020-10-22 23:25

smart921

等　级：新手上路
帖　子：107
专家分：9
注　册：2010-8-8

第 7 楼

得分:0

感谢二位版主！

2020-10-23 06:21