怎样把成绩通知单.txt读到表文件gkcj.dbf中？由于每个人的成绩不同，在文本文件中占位不一：有的成绩占2个字符，有的成绩占3个字符，研究了好长时间未弄好，现将有关数据、表格发上来，请高手指点，能提供完整代码则更好，如蒙赐教，万分感谢！！！

USE gkcj
ZAP
s = FILETOSTR("成绩通知单.txt")
n = ALINES(arr, s, 5, 0h0D0A,0h0D,0h0A,0hA1A1)
DIMENSION arr[n/7,7]
FOR i=1 TO ALEN(arr,1)
    ALINES(a1, arr[i,4], 5, " ")
    ALINES(a2, arr[i,3], 5, ":")
    ALINES(a3, arr[i,5], 5, ":")
    ALINES(a4, arr[i,7], 5, ":"," ")
    DIMENSION a4[5,2]
    INSERT INTO gkcj VALUES (a1[1],a1[2],a2[2],a3[2],;
        VAL(a4[1,2]),VAL(a4[2,2]),VAL(a4[3,2]),VAL(a4[4,2]),VAL(a4[5,2]))
ENDFOR
SELECT * FROM gkcj

CLOSE DATABASES 
USE gkcj
ZAP 
cStr = FILETOSTR("成绩通知单.txt")
FOR i = 1 TO ALINES(aa, cStr, 4 + 1, CHR(13) + CHR(10),CHR(13),CHR(10),CHR(41377)) STEP 7
    cBkqx = ALLTRIM(GETWORDNUM(aa[i + 2], 2, ":"))
    cKsh = GETWORDNUM(aa[i + 3], 1, " ")
    cXm = GETWORDNUM(aa[i + 3], 2, " ")
    cBmd = ALLTRIM(GETWORDNUM(aa[i + 4], 2, ":"))
    ALINES(bb, aa[i + 6], 4 + 1, " ", ":")
    INSERT INTO gkcj VALUES (cKsh, cXm, cBkqx, cBmd, VAL(bb[2]), VAL(bb[4]), VAL(bb[6]), VAL(bb[8]), VAL(bb[10]))
ENDFOR
SELECT gkcj
BROWSE 

[此贴子已经被作者于2020-4-25 11:30编辑过]