如题，我把EXCEL表用INSERT导入到DBF表。
8万条记录要2个小时，有没有快一点的方法？

上传相关文件看看，贴上你的代码

我的方法是:
1.将EXCEL文件另存95格式
2.用 APPE FROM 文件名 TYPE XL5

他说他有8万多条记录，你另存为95格式后，是不是只有65536条记录了？如果记录都丢失了，那你这样做还有什么意义

可以考试将EXCEL数据先传到数组里，再添加到DBF文件里吧

vfp表操作中记录指针乱回调也会影响录入速度。

最简单的办法，就是拆成两个60000条以内记录的文件，然后按照3楼的方法做。

8W记录,有多个个字段,每个字段的长度大概是什么,类型是什么.
模仿1下,测试对比看看

拆成多个表逐个导入，减少对系统资源的占用，也会提高速度。

*!*    从某个大的 Xlsx 文件提取数据的压力测试：
*!*    测试结果：某个 Xlsx 文件有116,000行，12M，SQL 耗时5秒，DBF = 32MB

Clear
Set Talk Off
Local lcXLBook As String, lnSQLHand As Integer, ;
    lcSQLCmd As String, lnSuccess As Integer, ;
    lcConnstr As String
Clear

lcXLBook = Getfile("xlsx")
lnSec = Seconds( )

lcConnstr = [Driver=] + ;
    [{Microsoft Excel Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)};] + ;
    [DBQ=] + lcXLBook

If !File( lcXLBook )
    ? [Excel 文件没找到]
    Return .F.
Endif
lnSQLHand = SqlStringConnect( lcConnstr )

lcSQLCmd = [Select * From "Sheet$"]  && Sheet Name in Excel
lnSuccess = SQLExec( lnSQLHand, lcSQLCmd, [xlResults] )
? [SQL 命令状态：], Iif( lnSuccess > 0, '成功！', '失败！' )
If lnSuccess < 0
    Local Array laErr[1]
    Aerror( laErr )
    ? laErr(3)
    SQLDisconnect( lnSQLHand )
    Return .F.
Endif

? "耗时：" + TRANSFORM( Seconds( ) - lnSec )
Select xlResults
Browse Normal
SQLDisconnect( lnSQLHand )