求汉字转区位码和区位码转汉字函数

[此贴子已经被作者于2017-7-18 10:16编辑过]

是区域码，还是区位码，令人费解。

如果是区位码问题，可以参照：https://blog.bccn.net/sdta/16760

https://blog.bccn.net/sdta/16760 无法打开

CREATE CURSOR T (S N(2))
FOR I=1 TO 94
    INSERT INTO T VALUES (I)
ENDFOR
SELECT PADL(A.S,2,[0])+PADL(B.S,2,[0]) AS QWM,CHR(160+A.S)+CHR(160+B.S) HZ,;
TRANSFORM(ASC(CHR(160+A.S)+CHR(160+B.S))) NASC FROM T A INNER JOIN T B ON A.S<=B.S OR A.S>B.S

** GB2312，编码：区码01--94、位码01--94。
** 双字节汉字编码，前字节：160+区码，后字节：160+位码。
? QWM_HZ(16, 1)
nQM = 0
nWM = 0
? HZ_QWM("啊", @nQM, @nWM)
? nQM
? nWM
RETURN

FUNCTION QWM_HZ(nQM, nWM)
    IF BETWEEN(nQM,1,94) AND BETWEEN(nWM,1,94)
        RETURN CHR(160+nQM)+CHR(160+nWM)
    ENDIF
    RETURN ""
ENDFUNC

FUNCTION HZ_QWM(cHZ, nQM, nWM)
    IF LEN(cHZ) == 2
        nQM = ASC(LEFT(cHZ,1)) - 160
        nWM = ASC(RIGHT(cHZ,1)) - 160
        IF BETWEEN(nQM,1,94) AND BETWEEN(nWM,1,94)
            RETURN PADL(nQM,2,"0")+PADL(nWM,2,"0")
        ENDIF
    ENDIF
    nQM = 0
    nWM = 0
    RETURN ""
ENDFUNC

[此贴子已经被作者于2017-7-18 16:43编辑过]

谢谢各位版主！