用cursoradapter 类生成的cursor,,brow可以看到.Grid 怎么获取不到?

oForm = Createobject("form1")
oForm.Show
Read Events
Define Class form1 As Form
    Caption = "CursorAdapter类示例"
    Name = "Form1"
    Add Object grid1 As Grid With ;
        Anchor = 15, ;
        Height = 229, ;
        Left = 6, ;
        Top = 12, ;
        Width = 361, ;
        Name = "Grid1"
    Procedure Load
        lo = Createobject("caODBC")
        Browse
    Endproc
    Procedure Init
        This.grid1.RecordSource = "客户"
        This.grid1.RecordSourceType = 1
    Endproc
    Procedure Destroy
        Clear Events
    Endproc
Enddefine
Define Class caodbc As CursorAdapter
    Height = 22
    Width = 23
    Alias = "客户"
    BufferModeOverride = 5
    DataSourceType = "ODBC"
    Name = "caodbc"
    Procedure Init
        Local lcConnStr, lnConn
        lcConnStr = "Driver=SQL Server;Server=(local);DATABASE=Northwind;uid=sa;pwd="
        lnConn = Sqlstringconnect(lcConnStr)
        If lnConn > 0 Then
            This.Datasource = lnConn
            This.SelectCmd = "SELECT * FROM Customers"
            This.CursorFill()
        Else
            Messagebox("连接失败!")
        Endif
    Endproc
    Procedure Destroy
        If This.Datasource > 0 Then
            SQLDisconnect(This.Datasource)
        Endif
    Endproc
Enddefine

[此贴子已经被作者于2016-3-1 18:56编辑过]

Grid你怎么设置？

代码发上去了,您给看看,卡了好久了.

CursorAdapter 也支持本地自由表，如果本地表正常，问题可能出在远程？

    Procedure Init
        This.grid1.RecordSource = "客户"
        This.grid1.RecordSourceType = 1
    Endproc

这里运行时改变了GRID的数据源，GRID被重新初始化了，可以去掉这两句，写到这里：
    Add Object grid1 As Grid With ;
        Anchor = 15, ;
        Height = 229, ;
        Left = 6, ;
        Top = 12, ;
        Width = 361, ;
        Name = "Grid1",;
        RecordSourceType = 1,;
        RecordSource = "客户"

[此贴子已经被作者于2016-3-1 20:17编辑过]

不是远程原因，获取的cursor用brow可以列示。

最初就是这样写的.没效果才改到form的init中。

留意过相关贴
是用了局部变量的问题
    Procedure Load
        lo = Createobject("caODBC")
        Browse   
    Endproc
这时Browse与lo同在一个作用域，brow可以看到。Load过程结束后，lo会被释放，GRID数据源关闭了。

是这个原因.谢谢!

设计时与运时的概念,讲过也是这样.